вот, кстати, ты же в отличие от меня настоящий программист. может, посоветуешь, почему vim не выравнивает разметку для jsp страниц:(((

Вот мой .vimrc, попробуй на нём, может быть с ним выровняется.

" F2 - View Trailing whitespaces
" F3 - Warplines off/on
" F4 - Code Folding (based on syntax)
" F5 - Unfold all folding code
" F6 - New tab
" F7 - Insert last
" F8 - Fix paste
" Space - Clear Highlights


" Global Settings
"" Set isn't compatibility mode with vi
set nocp
"" Set line with numbers
set number
"" Show syntax highlights
syntax on
"" Show command symbol on last line of terminal
set showcmd
"" Don't load buffer after swithing windows
set hidden
set history=1000
set nobackup
set termencoding=utf-8
"" Terminal colors
set t_Co=256

" Code Folding
set foldcolumn=1
set foldmethod=syntax
set nofoldenable

" Visualize symbols
set list
set listchars=tab:>-,trail:~,extends:>,precedes:<

" Vim functions

"" WarpLine Function
let g:WarpLines = 0
set wrap
set linebreak

function! WarpLines()
    if g:WarpLines
        set wrap
        set linebreak
        echo 'WarpLines is: on'
    else
        set nowrap
        set nolinebreak
        echo 'WarpLines is: off'
    endif
    let g:WarpLines = !g:WarpLines
endfunction

"" Visual Symbols function
""" Visual other symbols
""" Highlight whitespace problems.
""" flags is '' to clear highlighting, or is a string to
""" specify what to highlight (one or more characters):
"""   e  whitespace at end of line
"""   i  spaces used for indenting
"""   s  spaces before a tab
"""   t  tabs not at start of line
function! ShowWhitespace(flags)
  let bad = ''
  let pat = []
  for c in split(a:flags, '\zs')
    if c == 'e'
      call add(pat, '\s\+$')
    elseif c == 'i'
      call add(pat, '^\t*\zs \+')
    elseif c == 's'
      call add(pat, ' \+\ze\t')
    elseif c == 't'
      call add(pat, '[^\t]\zs\t\+')
    else
      let bad .= c
    endif
  endfor
  if len(pat) > 0
    let s = join(pat, '\|')
    exec 'syntax match ExtraWhitespace "'.s.'" containedin=ALL'
  else
    syntax clear ExtraWhitespace
  endif
  if len(bad) > 0
    echo 'ShowWhitespace ignored: '.bad
  endif
endfunction

function! ToggleShowWhitespace()
  if !exists('b:ws_show')
    let b:ws_show = 0
  endif
  if !exists('b:ws_flags')
    let b:ws_flags = 'eist'  " default (which whitespace to show)
  endif
  let b:ws_show = !b:ws_show
  if b:ws_show
    call ShowWhitespace(b:ws_flags)
    echo 'Show space and indent bugs is: on'
  else
    call ShowWhitespace('')
    echo 'Show space and indent bugs is: off'
  endif
endfunction

highlight ExtraWhitespace ctermbg=Red guibg=Red

"" AutoComplete Function
function! Tab_Or_Complete()
    if col('.')>1 && strpart( getline('.'), col('.')-2, 3 ) =~ '^\w'
        return "\<C-P>"
    else
        return "\<Tab>"
    endif
endfunction

" Mouse
set mouse=a
set mousemodel=popup

" StatusBar Settings
set ruler
"" StatusBar Format
set statusline=%f%m%r%h%w\ %y\ ff:%{&ff}\ enc:%{&enc}\ fenc:%{&fenc}%=Row:\ %2l/%L\ \ \ Column:%2c\ [%2p%%]
"" Show StatusBar Always
set laststatus=2

" Default Whitespace
set tabstop=4
set shiftwidth=4
set softtabstop=4
set expandtab
set smartindent

" Editor
"" Visualize brackets
set showmatch
"" Enable autoread file (if it changed)
set autoread
"" Enable warps on cursor
set whichwrap=<,>,[,],h,l
"" Show TabBar always
set stal=2

" Searching and Highlights
set hlsearch
set incsearch
set ignorecase
set smartcase

" Keys
"" Clear search highlightings
nmap <Space> :noh<Bar>:echo<CR>
map <silent> <F2> :call ToggleShowWhitespace()<CR>
map <silent> <F3> :call WarpLines()<CR>
imap <F4> <C-O>za
nmap <F4> za
omap <F4> <C-C>za
vmap <F4> zf
nmap <F5> :set nofoldenable<Bar>:echo 'Code Fold is: off'<CR>
nmap <F6> :tabnew<Bar>:echo<CR>
nmap <F7> @1
imap <Tab> <C-R>=Tab_Or_Complete()<CR>
imap <silent> <F8> <ESC>u:set paste<CR>.:set nopaste<CR>gi

" Commands completiton mode
set wildmenu
set wildmode=list:longest,list:full
"set wildignore+=*.o,*.obj

" Russian Keyboard command hack
set langmap=ёйцукенгшщзхъфывапролджэячсмитьбюЁЙЦУКЕHГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮ;`qwertyuiop[]asdfghjkl\\;'zxcvbnm\\,.~QWERTYUIOP{}ASDFGHJKL:\\"ZXCVBNM<>

" Other Settings
set backspace=indent,eol,start

filetype on
filetype plugin on
filetype indent on

Хех, jsp, прямо как 15 лет назад.